This is the mail archive of the
gdb-patches@sources.redhat.com
mailing list for the GDB project.
[PATCH] Rewrite testsuite/configure.in
- From: Mark Kettenis <kettenis at chello dot nl>
- To: gdb-patches at sources dot redhat dot com
- Date: Sat, 28 Dec 2002 23:14:09 +0100 (CET)
- Subject: [PATCH] Rewrite testsuite/configure.in
Since we're talking about the transition to Autoconf 2.5x, I've
started a cleanup of the various configure.in files in GDB. The idea
is to make the new configure.in files compatible with both Autoconf
2.13 and Autoconf 2.5x (where x=3 for now, since that's the version of
Autoconf that's installed on my FreeBSD 4.7-RELEASE-p2 system that I
use to hack on). In the process I try to modernize the files as much
as possible, such that the differences between the files and a true
Autoconf 2.5x configure.ac will be minimal.
Attached is a patch that takes a stab at testsuite/configure.in.
Processing this file with Autoconf 2.53 provokes the following
warning:
configure.in:114: warning: AC_CONFIG_SUBDIRS: you should use literals
which unfortunately is unavoidable.
Since the patch is a wee bit unreadable, here's the new configure.in verbatim:
# -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
# Copyright (C) 2002
# Free Software Foundation, Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.
AC_PREREQ(2.13)
AC_INIT(gdb.base)
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
# Directories to use in all configurations.
AC_CONFIG_SUBDIRS(gdb.arch gdb.asm gdb.base gdb.c++ gdb.java gdb.disasm)
AC_CONFIG_SUBDIRS(gdb.mi gdb.threads gdb.trace)
configdirs=
# Add HP-specific tests when appropriate.
case $target in
hppa*-*-hpux*)
configdirs="$configdirs gdb.hp" ;;
esac
# With stabs.
AC_ARG_WITH(stabs,
[ --with-stabs arrange to use stabs instead of host debug format],,
[# We enable stabs tests by default on selected targets.
case $target in
powerpc-*-aix* \
| rs6000-*-aix* \
| *-*-bsd* \
| *-*-go32* \
| *-*-linux* \
| *-*-lynxos* \
| *-sun-* \
| hppa*-*-* \
| *-*-elf* \
)
with_stabs=yes ;;
*)
with_stabs=no ;;
esac])
# Add stabs tests when appropriate.
if test $with_stabs = yes; then
configdirs="$configdirs gdb.stabs"
fi
# Enable gdbtk.
AC_ARG_ENABLE(gdbtk,
[ --enable-gtk enable gdbtk graphical user interface (GUI)],,
[if test -d $srcdir/gdb.gdbtk; then
enable_gdbtk=yes
else
enable_gdbtk=no
fi])
# We unconditionally disable gdbtk tests on selected platforms.
case $host in
*go32* | *windows*)
enable_gdbtk=no ;;
esac
# Add gdbtk tests when appropriate.
if test $enable_gdbtk = yes; then
configdirs="$configdirs gdb.gdbtk"
fi
# Enable shared libraries.
AC_ARG_ENABLE(shared,
[ --enable-shared build shared libraries [deault=yes]],,
enable_shared=yes)
# If we have shared libraries, try to set RPATH_ENVVAR reasonably,
# such that we can find the shared libraries in the build tree.
if test $enable_shared = no; then
# The variable `RPATH_ENVVAR' itself is not likely to be used on any
# platform.
RPATH_ENVVAR=RPATH_ENVVAR
else
# The variable `LD_LIBRARY_PATH' is used on most platforms.
RPATH_ENVVAR=LD_LIBRARY_PATH
# The following exceptions are taken from Libtool 1.4.3.
case $host_os in
aix*)
if test $host_cpu != ia64; then
RPATH_ENVVAR=LIBPATH
fi ;;
darwin* | rhapsody*)
RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
hpux*)
RPATH_ENVVAR=SHLIB_PATH ;;
esac
fi
AC_SUBST(RPATH_ENVVAR)
AC_EXEEXT
AC_CONFIG_SUBDIRS($configdirs)
AC_OUTPUT(Makefile)
If there are no objections, I'll check this in in a week or so.
Mark
Index: testsuite/ChangeLog
from Mark Kettenis <kettenis@gnu.org>
* configure.in: Rewrite.
* configure: Regenerated.
Index: testsuite/configure.in
===================================================================
RCS file: /cvs/src/src/gdb/testsuite/configure.in,v
retrieving revision 1.6
diff -u -p -r1.6 configure.in
--- testsuite/configure.in 1 Aug 2002 17:18:35 -0000 1.6
+++ testsuite/configure.in 28 Dec 2002 21:57:51 -0000
@@ -1,116 +1,115 @@
-dnl Process this file file with autoconf to produce a configure script.
-dnl This file is a shell script fragment that supplies the information
-dnl necessary to tailor a template configure script into the configure
-dnl script appropriate for this directory. For more information, check
-dnl any existing configure script.
+# -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
-AC_PREREQ(2.12.1)
+# Copyright (C) 2002
+# Free Software Foundation, Inc.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
+# 02111-1307, USA.
+
+AC_PREREQ(2.13)
AC_INIT(gdb.base)
-CC=${CC-cc}
-AC_SUBST(CC)
-AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/../..)
-AC_CANONICAL_SYSTEM
+AC_CANONICAL_BUILD
+AC_CANONICAL_HOST
+AC_CANONICAL_TARGET
# Directories to use in all configurations.
-configdirs="gdb.arch \
- gdb.asm \
- gdb.base \
- gdb.c++ \
- gdb.java \
- gdb.disasm \
- gdb.mi \
- gdb.threads \
- gdb.trace"
-
-
-# Directories to use for a configuration which uses stabs.
-stabsdirs="gdb.stabs"
-
- # this section is for targets that use stabs
-# add stabs tests for appropriate targets
-case "${target}" in
- powerpc-*-aix*) configdirs="${configdirs} ${stabsdirs}" ;;
- rs6000-*-aix*) configdirs="${configdirs} ${stabsdirs}" ;;
- *-*-bsd*) configdirs="${configdirs} ${stabsdirs}" ;;
- *-*-go32*) configdirs="${configdirs} ${stabsdirs}" ;;
- *-*-linux*) configdirs="${configdirs} ${stabsdirs}" ;;
- *-*-lynxos*) configdirs="${configdirs} ${stabsdirs}" ;;
- *-sun-*) configdirs="${configdirs} ${stabsdirs}" ;;
- hppa*-*-*) configdirs="${configdirs} ${stabsdirs}" ;;
- *-*-elf*) configdirs="${configdirs} ${stabsdirs}" ;;
- *) if test "x${with_stabs}" = x"yes" ; then
- configdirs="${configdirs} ${stabsdirs}"
- fi ;;
+AC_CONFIG_SUBDIRS(gdb.arch gdb.asm gdb.base gdb.c++ gdb.java gdb.disasm)
+AC_CONFIG_SUBDIRS(gdb.mi gdb.threads gdb.trace)
+configdirs=
+
+# Add HP-specific tests when appropriate.
+case $target in
+ hppa*-*-hpux*)
+ configdirs="$configdirs gdb.hp" ;;
esac
-# Directory with HP specific tests. They will run only with HP's compilers.
-# These tests will not work on other platforms and compilers.
-
-hpdir="gdb.hp"
+# With stabs.
+AC_ARG_WITH(stabs,
+[ --with-stabs arrange to use stabs instead of host debug format],,
+[# We enable stabs tests by default on selected targets.
+case $target in
+ powerpc-*-aix* \
+ | rs6000-*-aix* \
+ | *-*-bsd* \
+ | *-*-go32* \
+ | *-*-linux* \
+ | *-*-lynxos* \
+ | *-sun-* \
+ | hppa*-*-* \
+ | *-*-elf* \
+ )
+ with_stabs=yes ;;
+ *)
+ with_stabs=no ;;
+esac])
+
+# Add stabs tests when appropriate.
+if test $with_stabs = yes; then
+ configdirs="$configdirs gdb.stabs"
+fi
-case "${target}" in
- hppa*-*-hpux*) configdirs="${configdirs} ${hpdir}" ;;
+# Enable gdbtk.
+AC_ARG_ENABLE(gdbtk,
+[ --enable-gtk enable gdbtk graphical user interface (GUI)],,
+ [if test -d $srcdir/gdb.gdbtk; then
+ enable_gdbtk=yes
+ else
+ enable_gdbtk=no
+ fi])
+# We unconditionally disable gdbtk tests on selected platforms.
+case $host in
+ *go32* | *windows*)
+ enable_gdbtk=no ;;
esac
+# Add gdbtk tests when appropriate.
+if test $enable_gdbtk = yes; then
+ configdirs="$configdirs gdb.gdbtk"
+fi
-# Begin stuff to support --enable-shared
+# Enable shared libraries.
AC_ARG_ENABLE(shared,
-[ --enable-shared use shared libraries],
-[case "${enableval}" in
- yes) shared=true ;;
- no) shared=false ;;
- *) shared=true ;;
-esac])dnl
-RPATH_ENVVAR=LD_LIBRARY_PATH
-# If we have shared libraries, try to set RPATH_ENVVAR reasonably.
-if test "${shared}" = "true"; then
- case "${host}" in
- *-*-hpux*)
- RPATH_ENVVAR=SHLIB_PATH
- ;;
+[ --enable-shared build shared libraries [deault=yes]],,
+ enable_shared=yes)
+
+# If we have shared libraries, try to set RPATH_ENVVAR reasonably,
+# such that we can find the shared libraries in the build tree.
+if test $enable_shared = no; then
+ # The variable `RPATH_ENVVAR' itself is not likely to be used on any
+ # platform.
+ RPATH_ENVVAR=RPATH_ENVVAR
+else
+ # The variable `LD_LIBRARY_PATH' is used on most platforms.
+ RPATH_ENVVAR=LD_LIBRARY_PATH
+ # The following exceptions are taken from Libtool 1.4.3.
+ case $host_os in
+ aix*)
+ if test $host_cpu != ia64; then
+ RPATH_ENVVAR=LIBPATH
+ fi ;;
+ darwin* | rhapsody*)
+ RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
+ hpux*)
+ RPATH_ENVVAR=SHLIB_PATH ;;
esac
fi
AC_SUBST(RPATH_ENVVAR)
-# End stuff to support --enable-shared
-# Start stuff to support --enable-gdbtk
-AC_ARG_ENABLE(gdbtk,
-[ --enable-gdbtk ],
-[case "${enableval}" in
- yes)
- case "$host" in
- *go32*)
- enable_gdbtk=no ;;
- *windows*)
- enable_gdbtk=no ;;
- *)
- enable_gdbtk=yes ;;
- esac ;;
- no)
- enable_gdbtk=no ;;
- *)
- AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
-esac],
-[
-# Default is on for everything but go32 and windows
-case "$host" in
- *go32* | *windows*)
- ;;
- *)
- enable_gdbtk=yes ;;
- esac
-])
-if test "${enable_gdbtk}" = "yes"; then
- configdirs="${configdirs} gdb.gdbtk"
-fi
-# End stuff to support --enable-shared
-
-dnl Check for exe extension set on certain hosts (e.g. Win32)
AC_EXEEXT
-# configure the subdirectories too
AC_CONFIG_SUBDIRS($configdirs)
-
-dnl AC_SUBST(gdb_target_cpu)
AC_OUTPUT(Makefile)