This is the mail archive of the
gdb-patches@sourceware.org
mailing list for the GDB project.
Re: [patch] add --with-expat configure option
- From: Daniel Jacobowitz <drow at false dot org>
- To: Thiago Jung Bauermann <bauerman at br dot ibm dot com>
- Cc: gdb-patches <gdb-patches at sourceware dot org>, Baurzhan Ismagulov <ibr at radix50 dot net>
- Date: Mon, 3 Sep 2007 16:47:24 -0400
- Subject: Re: [patch] add --with-expat configure option
- References: <1176510719.13824.25.camel@localhost.localdomain>
On Fri, Apr 13, 2007 at 09:31:59PM -0300, Thiago Jung Bauermann wrote:
> Hi,
>
> I needed to disable compiling with the expat library even if present in
> the build system, so I created a --with-expat configure option to
> control that. Configuring with --with-expat=no or --without-expat will
> disable the expat test. The default is to use the library if available.
>
> I'm posting here in case you are interested in incorporating the
> change...
Thanks. I decided to check in this version instead; it makes missing
expat a fatal error if --with-expat is given. This is useful for
people who do automated builds and expect them to have consistent
features.
--
Daniel Jacobowitz
CodeSourcery
2007-09-03 Daniel Jacobowitz <dan@codesourcery.com>
* configure.ac: Add --with-expat.
* configure: Regenerated.
Index: configure.ac
===================================================================
RCS file: /cvs/src/src/gdb/configure.ac,v
retrieving revision 1.50
diff -u -p -r1.50 configure.ac
--- configure.ac 3 Sep 2007 19:00:16 -0000 1.50
+++ configure.ac 3 Sep 2007 20:44:18 -0000
@@ -352,15 +352,30 @@ AC_SUBST(READLINE)
AC_SUBST(READLINE_DEPS)
AC_SUBST(READLINE_CFLAGS)
-AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
- [XML_Parser p = XML_ParserCreate (0);])
-if test "$HAVE_LIBEXPAT" != yes; then
- AC_MSG_WARN([expat is missing or unusable; some features may be disabled.])
+AC_ARG_WITH(expat,
+ AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
+ [], [with_expat=auto])
+AC_MSG_CHECKING([whether to use expat])
+AC_MSG_RESULT([$with_expat])
+
+if test "${with_expat}" = no; then
+ AC_MSG_WARN([expat support disabled; some features may be unavailable.])
+ HAVE_LIBEXPAT=no
else
- save_LIBS=$LIBS
- LIBS="$LIBS $LIBEXPAT"
- AC_CHECK_FUNCS(XML_StopParser)
- LIBS=$save_LIBS
+ AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
+ [XML_Parser p = XML_ParserCreate (0);])
+ if test "$HAVE_LIBEXPAT" != yes; then
+ if test "$with_expat" = yes; then
+ AC_MSG_ERROR([expat is missing or unusable])
+ else
+ AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
+ fi
+ else
+ save_LIBS=$LIBS
+ LIBS="$LIBS $LIBEXPAT"
+ AC_CHECK_FUNCS(XML_StopParser)
+ LIBS=$save_LIBS
+ fi
fi
# ------------------------- #